From c1d9af57156f3c95590d9a12c394ee064df9696e Mon Sep 17 00:00:00 2001
From: adikro <adikro@disroot.org>
Date: Sat, 20 Dec 2025 15:25:38 +0100
Subject: added disko config for laptop, added storage and memory modules

---
 sys/core/memory.nix | 46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 sys/core/memory.nix

(limited to 'sys/core/memory.nix')

diff --git a/sys/core/memory.nix b/sys/core/memory.nix
new file mode 100644
index 0000000..cdf71e8
--- /dev/null
+++ b/sys/core/memory.nix
@@ -0,0 +1,46 @@
+{ config, lib, ... }:
+let
+  cfg = config.sys.core.memory;
+in
+{
+  options.sys.core.memory = {
+    enable = lib.mkEnableOption "memory management";
+
+    zram = {
+      enable = lib.mkEnableOption "enables zram compression";
+      percent = lib.mkOption {
+        type = lib.types.int;
+        default = 25;
+        description = "Percentage of total RAM to use for zram";
+      };
+    };
+
+    swapfile = {
+      enable = lib.mkEnableOption "enables a swapfile";
+      size = lib.mkOption {
+        type = lib.types.int;
+        default = 8192;
+        description = "Size of the swapfile in gigabytes";
+      };
+    };
+  };
+
+  config = lib.mkIf cfg.enable (lib.mkMerge [
+    (lib.mkIf cfg.zram.enable {
+      zramSwap = {
+        enable = true;
+        algorithm = "zstd";
+        memoryPercent = cfg.zram.percent;
+        priority = 100;
+      };
+    })
+
+    (lib.mkIf cfg.swapfile.enable {
+      swapDevices = [ {
+        device = "/.swapvol/swapfile";
+        size = cfg.swapfile.size * 1024;
+        priority = 0;
+      } ];
+    })
+  ]);
+}
-- 
cgit v1.3