summaryrefslogtreecommitdiff
path: root/sys
diff options
context:
space:
mode:
Diffstat (limited to 'sys')
-rw-r--r--sys/core/audio.nix32
-rw-r--r--sys/core/bootloader.nix42
-rw-r--r--sys/core/core.nix46
-rw-r--r--sys/core/drivers.nix47
-rw-r--r--sys/core/fonts.nix22
-rw-r--r--sys/core/greet.nix29
-rw-r--r--sys/core/home-manager.nix36
-rw-r--r--sys/core/localization.nix41
-rw-r--r--sys/core/memory.nix41
-rw-r--r--sys/core/networking.nix20
-rw-r--r--sys/core/power.nix18
-rw-r--r--sys/core/security.nix39
-rw-r--r--sys/core/storage.nix36
-rw-r--r--sys/core/users.nix23
-rw-r--r--sys/default.nix8
-rw-r--r--sys/srv/compat.nix24
-rw-r--r--sys/srv/docker.nix14
-rw-r--r--sys/srv/files.nix46
-rw-r--r--sys/srv/gaming.nix50
-rw-r--r--sys/srv/kvm.nix18
-rw-r--r--sys/srv/nix-helper.nix23
-rw-r--r--sys/srv/ollama.nix28
-rw-r--r--sys/srv/srv.nix12
-rw-r--r--sys/wm/niri.nix21
-rw-r--r--sys/wm/wm.nix20
25 files changed, 0 insertions, 736 deletions
diff --git a/sys/core/audio.nix b/sys/core/audio.nix
deleted file mode 100644
index 234b6bd..0000000
--- a/sys/core/audio.nix
+++ /dev/null
@@ -1,32 +0,0 @@
-{ config, lib, pkgs, username, ... }:
-let
- cfg = config.sys.core.audio;
-in
-{
- options.sys.core.audio.enable = lib.mkEnableOption "audio support";
- config = lib.mkIf cfg.enable {
- services = {
- pipewire = {
- enable = true;
- audio.enable = true;
- pulse.enable = true;
- alsa.enable = true;
- alsa.support32Bit = true;
- jack.enable = true;
- wireplumber.enable = true;
- };
- playerctld.enable = true;
- spotifyd.enable = true;
- };
-
- security.rtkit.enable = true;
- hardware.enableAllFirmware = true;
-
- environment.systemPackages = with pkgs; [
- helvum
- alsa-utils
- ];
-
- home-manager.users.${username}.hm.soft.easyeffects.enable = true;
- };
-}
diff --git a/sys/core/bootloader.nix b/sys/core/bootloader.nix
deleted file mode 100644
index ff0aad5..0000000
--- a/sys/core/bootloader.nix
+++ /dev/null
@@ -1,42 +0,0 @@
-{ config, lib, ... }:
-let
- cfg = config.sys.core.bootloader;
-in
-{
- options.sys.core.bootloader = lib.mkOption {
- type = lib.types.enum [ "systemd-boot" "grub" "none" ];
- default = "systemd-boot";
- description = "which bootloader to use";
- };
- config = lib.mkMerge [
- {
- boot.loader.efi.canTouchEfiVariables = true;
- boot.supportedFilesystems = [ "ntfs" ];
- boot.kernelParams = [ "quiet" "splash" ];
- }
-
- (lib.mkIf (cfg == "systemd-boot") {
- boot.consoleLogLevel = 0;
- boot.loader = {
- systemd-boot.enable = true;
- systemd-boot.editor = false;
- timeout = 0;
- };
- })
-
- (lib.mkIf (cfg == "grub") {
- boot.loader = {
- timeout = 3;
- efi.efiSysMountPoint = "/boot";
- grub = {
- enable = true;
- device = "nodev";
- efiSupport = true;
- useOSProber = true;
-
- default = 2;
- };
- };
- })
- ];
-}
diff --git a/sys/core/core.nix b/sys/core/core.nix
deleted file mode 100644
index 428d7ea..0000000
--- a/sys/core/core.nix
+++ /dev/null
@@ -1,46 +0,0 @@
-{ config, lib, pkgs, ... }:
-let
- cfg = config.sys.core;
-in
-{
- imports = [
- ./audio.nix
- ./bootloader.nix
- ./drivers.nix
- ./fonts.nix
- ./greet.nix
- ./home-manager.nix
- ./localization.nix
- ./memory.nix
- ./networking.nix
- ./power.nix
- ./security.nix
- ./storage.nix
- ./users.nix
- ];
-
- options.sys.core = {
- allowUnfree.enable = lib.mkEnableOption "unfree software";
-
- flatpak.enable = lib.mkEnableOption "Flatpak support";
-
- hardwareTools = {
- enable = lib.mkEnableOption "peripheral and thermal tools";
- };
- };
-
- config = lib.mkMerge [
- (lib.mkIf cfg.allowUnfree.enable {
- nixpkgs.config.allowUnfree = true;
- })
-
- (lib.mkIf cfg.flatpak.enable {
- services.flatpak.enable = true;
- })
-
- (lib.mkIf cfg.hardwareTools.enable {
- programs.coolercontrol.enable = true;
- environment.systemPackages = [ pkgs.rivalcfg ];
- })
- ];
-}
diff --git a/sys/core/drivers.nix b/sys/core/drivers.nix
deleted file mode 100644
index c769786..0000000
--- a/sys/core/drivers.nix
+++ /dev/null
@@ -1,47 +0,0 @@
-{ config, lib, pkgs, ... }:
-let
- cfg = config.sys.core.drivers;
-in
-{
- options.sys.core.drivers = {
- enable = lib.mkEnableOption "enables hardware drivers";
- amd.enable = lib.mkEnableOption "AMD specific drivers and microcode";
- stability = lib.mkOption {
- type = lib.types.enum [ "stable" "unstable" ];
- default = "stable";
- };
- };
- config = lib.mkIf cfg.enable (lib.mkMerge [
- {
- services.smartd.enable = true;
- hardware.sensor.iio.enable = true;
- hardware.enableAllFirmware = true;
- hardware.cpu.amd.updateMicrocode = true;
- hardware.graphics = {
- enable = true;
- enable32Bit = true;
- };
- }
-
- (lib.mkIf cfg.amd.enable {
- services.xserver.videoDrivers = [ "amdgpu" ];
- hardware.amdgpu = {
- initrd.enable = true;
- overdrive.enable = true;
- };
- })
-
- (lib.mkIf (cfg.amd.enable && cfg.stability == "unstable") {
- services.lact.enable = true;
- boot.kernelPackages = pkgs.linuxPackages_cachyos-lto-znver4;
- chaotic.mesa-git = {
- enable = true;
- extraPackages = [ pkgs.mesa_git.opencl ];
- };
- })
-
- (lib.mkIf (cfg.amd.enable && cfg.stability == "stable") {
- boot.kernelPackages = pkgs.linuxPackages_latest;
- })
- ]);
-}
diff --git a/sys/core/fonts.nix b/sys/core/fonts.nix
deleted file mode 100644
index 1173439..0000000
--- a/sys/core/fonts.nix
+++ /dev/null
@@ -1,22 +0,0 @@
-{ config, lib, pkgs, ... }:
-let
- cfg = config.sys.core.fonts;
-in
-{
- options.sys.core.fonts.enable = lib.mkEnableOption "system-wide font and console configuration";
-
- config = lib.mkIf cfg.enable {
- console = {
- keyMap = "pl";
- earlySetup = true;
- font = "ter-v32n";
- packages = with pkgs; [ terminus_font ];
- };
-
- fonts.packages = with pkgs; [
- nerd-fonts.jetbrains-mono
- nerd-fonts.fira-mono
- nerd-fonts.fira-code
- ];
- };
-}
diff --git a/sys/core/greet.nix b/sys/core/greet.nix
deleted file mode 100644
index 95603e8..0000000
--- a/sys/core/greet.nix
+++ /dev/null
@@ -1,29 +0,0 @@
-{ config, lib, pkgs, ... }:
-let
- cfg = config.sys.core.greet;
-in
-{
- options.sys.core.greet.enable = lib.mkEnableOption "enables greetd daemon with tuigreet";
- config = lib.mkIf cfg.enable {
- services.greetd = {
- enable = true;
- settings = {
- default_session = {
- user = "greeter";
- command = ''
- ${pkgs.tuigreet}/bin/tuigreet \
- --sessions ${config.services.displayManager.sessionData.desktops}/share/xsessions:${config.services.displayManager.sessionData.desktops}/share/wayland-sessions \
- --remember \
- --remember-user-session \
- --asterisks \
- --greeting 'Welcome to NixOS!' \
- --time
- '';
- };
- };
- };
- security.pam.services.greetd.enableGnomeKeyring = true;
-
- environment.systemPackages = with pkgs; [ tuigreet ];
- };
-}
diff --git a/sys/core/home-manager.nix b/sys/core/home-manager.nix
deleted file mode 100644
index 7bc4b18..0000000
--- a/sys/core/home-manager.nix
+++ /dev/null
@@ -1,36 +0,0 @@
-{ inputs, config, lib, username, ... }:
-let
- cfg = config.sys.core.home-manager;
-in
-{
- imports = [ inputs.home-manager.nixosModules.home-manager ];
-
- options.sys.core.home-manager = {
- enable = lib.mkEnableOption "home Manager configuration";
-
- users = lib.mkOption {
- default = {};
- description = "Attribute set of users and their home-manager configurations";
- type = lib.types.attrsOf (lib.types.submodule {
- options = {
- path = lib.mkOption {
- type = lib.types.path;
- description = "Path to the user's home.nix file";
- };
- };
- });
- };
- };
- config = lib.mkIf cfg.enable {
- home-manager = {
- extraSpecialArgs = { inherit inputs username; };
- useGlobalPkgs = true;
- useUserPackages = true;
- backupFileExtension = "bak";
-
- users = lib.mapAttrs (name: userCfg: {
- imports = [ userCfg.path ];
- }) cfg.users;
- };
- };
-}
diff --git a/sys/core/localization.nix b/sys/core/localization.nix
deleted file mode 100644
index 4d45b75..0000000
--- a/sys/core/localization.nix
+++ /dev/null
@@ -1,41 +0,0 @@
-{ config, lib, ... }:
-let
- cfg = config.sys.core.locale;
-in
-{
- options.sys.core.locale = {
- enable = lib.mkEnableOption "system localization (timezone and language)";
-
- timeZone = lib.mkOption {
- type = lib.types.str;
- default = "Europe/Warsaw";
- description = "the system timezone.";
- };
-
- format = lib.mkOption {
- type = lib.types.str;
- default = "pl_PL.UTF-8";
- description = "the locale used for numbers, time, and measurements.";
- };
- };
- config = lib.mkIf cfg.enable {
- time.timeZone = cfg.timeZone;
-
- i18n = {
- defaultLocale = "en_US.UTF-8";
-
- extraLocaleSettings = {
- LC_TIME = cfg.format;
- LC_NUMERIC = cfg.format;
- LC_MONETARY = cfg.format;
- LC_PAPER = cfg.format;
- LC_MEASUREMENT = cfg.format;
- LC_COLLATE = cfg.format;
- LC_NAME = cfg.format;
- LC_ADDRESS = cfg.format;
- LC_TELEPHONE = cfg.format;
- LC_IDENTIFICATION = cfg.format;
- };
- };
- };
-}
diff --git a/sys/core/memory.nix b/sys/core/memory.nix
deleted file mode 100644
index 956cc73..0000000
--- a/sys/core/memory.nix
+++ /dev/null
@@ -1,41 +0,0 @@
-{ config, lib, ... }:
-let
- cfg = config.sys.core.memory;
-in
-{
- options.sys.core.memory = {
- zram = {
- enable = lib.mkEnableOption "enables zram compression";
- percent = lib.mkOption {
- type = lib.types.int;
- default = 25;
- };
- };
-
- swapfile = {
- enable = lib.mkEnableOption "enables a swapfile";
- size = lib.mkOption {
- type = lib.types.int;
- default = 8;
- };
- };
- };
- config = lib.mkMerge [
- (lib.mkIf cfg.zram.enable {
- zramSwap = {
- enable = true;
- algorithm = "zstd";
- memoryPercent = cfg.zram.percent;
- priority = 100;
- };
- })
-
- (lib.mkIf cfg.swapfile.enable {
- swapDevices = [ {
- device = "/.swapvol/swapfile";
- size = cfg.swapfile.size * 1024;
- priority = 0;
- } ];
- })
- ];
-}
diff --git a/sys/core/networking.nix b/sys/core/networking.nix
deleted file mode 100644
index 314feb7..0000000
--- a/sys/core/networking.nix
+++ /dev/null
@@ -1,20 +0,0 @@
-{ config, lib, ... }:
-let
- cfg = config.sys.core.network;
-in
-{
- options.sys.core.network.enable = lib.mkEnableOption "system-wide networking setup";
- config = lib.mkIf cfg.enable {
- networking = {
- networkmanager = {
- enable = true;
- wifi.macAddress = "stable-ssid";
- ethernet.macAddress = "stable-ssid";
- };
- firewall = {
- enable = true;
- };
- };
- systemd.services."NetworkManager-wait-online".enable = false;
- };
-}
diff --git a/sys/core/power.nix b/sys/core/power.nix
deleted file mode 100644
index f67665e..0000000
--- a/sys/core/power.nix
+++ /dev/null
@@ -1,18 +0,0 @@
-{ config, lib, ... }:
-let
- cfg = config.sys.core.power;
-in
-{
- options.sys.core.power.enable = lib.mkEnableOption "enables AMD-optimized power management";
- config = lib.mkIf cfg.enable {
- services.power-profiles-daemon.enable = true;
-
- boot.kernelParams = [
- "amd_pstate=active"
- "nvme_core.default_ps_max_latency_us=0"
- ];
-
- powerManagement.powertop.enable = true;
- services.thermald.enable = true;
- };
-}
diff --git a/sys/core/security.nix b/sys/core/security.nix
deleted file mode 100644
index bf43577..0000000
--- a/sys/core/security.nix
+++ /dev/null
@@ -1,39 +0,0 @@
-{ config, lib, pkgs, ... }:
-let
- cfg = config.sys.core.security;
-in
-{
- options.sys.core.security.enable = lib.mkEnableOption "core security services";
- config = lib.mkIf cfg.enable {
- services.gnome.gnome-keyring.enable = true;
-
- security = {
- polkit.enable = true;
- rtkit.enable = true;
- };
-
- programs.gnupg.agent = {
- enable = true;
- enableSSHSupport = true;
- pinentryPackage = pkgs.pinentry-curses;
- };
-
- systemd.user.services.polkit-gnome-authentication-agent-1 = {
- description = "gnome-polkit-authentication-agent-1";
- wantedBy = [ "graphical-session.target" ];
- serviceConfig = {
- Type = "simple";
- ExecStart = "${pkgs.polkit_gnome}/libexec/polkit-gnome-authentication-agent-1";
- Restart = "on-failure";
- RestartSec = 1;
- TimeoutStopSec = 10;
- };
- };
-
- environment.systemPackages = with pkgs; [
- veracrypt
- bitwarden-desktop
- hello
- ];
- };
-}
diff --git a/sys/core/storage.nix b/sys/core/storage.nix
deleted file mode 100644
index 693e5e7..0000000
--- a/sys/core/storage.nix
+++ /dev/null
@@ -1,36 +0,0 @@
-{ config, lib, ... }:
-let
- cfg = config.sys.core.storage;
-in
-{
- options.sys.core.storage = {
- enable = lib.mkEnableOption "enables storage management";
-
- keepDays = lib.mkOption {
- type = lib.types.int;
- default = 14;
- description = "Number of days to keep old Nix generations before GC";
- };
- };
- config = lib.mkIf cfg.enable {
- nix.settings.auto-optimise-store = true;
-
- programs.nh = {
- enable = true;
- clean.enable = true;
- clean.extraArgs = "--keep-days ${toString cfg.keepDays} --keep 5";
- };
-
- services.fstrim.enable = true;
-
- services.btrfs.autoScrub = {
- enable = true;
- fileSystems = [ "/" ];
- };
-
- boot.tmp = {
- useTmpfs = true;
- tmpfsSize = "50%";
- };
- };
-}
diff --git a/sys/core/users.nix b/sys/core/users.nix
deleted file mode 100644
index fb4e7f0..0000000
--- a/sys/core/users.nix
+++ /dev/null
@@ -1,23 +0,0 @@
-{ config, lib, pkgs, username, ... }:
-let
- cfg = config.sys.core.users;
-in
-{
- options.sys.core.users.enable = lib.mkEnableOption "enables user accounts";
- config = lib.mkIf cfg.enable {
- programs.fish.enable = true;
- users.users.${username} = {
- isNormalUser = true;
- shell = pkgs.fish;
-
- extraGroups = lib.mkMerge [
- [ "wheel" ]
-
- (lib.mkIf (config.sys.core.drivers.amd.enable or false) [ "video" "render" ])
- (lib.mkIf (config.sys.core.network.enable or false) [ "networkmanager" ])
- (lib.mkIf (config.sys.srv.kvm.enable or false) [ "libvirtd" ])
- (lib.mkIf (config.sys.srv.docker.enable or false) [ "docker" ])
- ];
- };
- };
-}
diff --git a/sys/default.nix b/sys/default.nix
deleted file mode 100644
index 225c08f..0000000
--- a/sys/default.nix
+++ /dev/null
@@ -1,8 +0,0 @@
-{ ... }:
-{
- imports = [
- ./core/core.nix
- ./srv/srv.nix
- ./wm/wm.nix
- ];
-}
diff --git a/sys/srv/compat.nix b/sys/srv/compat.nix
deleted file mode 100644
index ab9560f..0000000
--- a/sys/srv/compat.nix
+++ /dev/null
@@ -1,24 +0,0 @@
-{ config, lib, pkgs, ... }:
-let
- cfg = config.sys.srv.compat;
-in
-{
- options.sys.srv.compat.enable = lib.mkEnableOption "enables compatibility with windows & x11";
- config = lib.mkIf cfg.enable {
- programs.xwayland = {
- enable = true;
- package = pkgs.xwayland-satellite;
- };
-
- environment.sessionVariables = {
- NIXOS_OZONE_WL = "1";
- ELECTRON_ENABLE_WAYLAND = "1";
- WINE_RT_PRIO = "1";
- };
-
- environment.systemPackages = with pkgs; [
- winetricks
- wineWowPackages.waylandFull
- ];
- };
-}
diff --git a/sys/srv/docker.nix b/sys/srv/docker.nix
deleted file mode 100644
index 0ed1541..0000000
--- a/sys/srv/docker.nix
+++ /dev/null
@@ -1,14 +0,0 @@
-{ config, lib, pkgs, username, ... }:
-let
- cfg = config.sys.srv.docker;
-in
-{
- options.sys.srv.docker.enable = lib.mkEnableOption "enables the docker container engine";
- config = lib.mkIf cfg.enable {
- virtualisation.docker.enable = true;
-
- environment.systemPackages = [ pkgs.docker-compose ];
-
- users.users.${username}.extraGroups = [ "docker" ];
- };
-}
diff --git a/sys/srv/files.nix b/sys/srv/files.nix
deleted file mode 100644
index 9b5759e..0000000
--- a/sys/srv/files.nix
+++ /dev/null
@@ -1,46 +0,0 @@
-{ config, lib, pkgs, ... }:
-let
- cfg = config.sys.srv.files;
-in
-{
- options.sys.srv.files = {
- thunar.enable = lib.mkEnableOption "enables the thunar file manager";
- utils.enable = lib.mkEnableOption "enables compression and trash utilities";
- };
- config = lib.mkMerge [
- {
- sys.srv.files.utils.enable = lib.mkDefault cfg.thunar.enable;
- }
-
- (lib.mkIf cfg.thunar.enable {
- programs.thunar = {
- enable = true;
- plugins = with pkgs.xfce; [
- thunar-volman
- thunar-archive-plugin
- thunar-vcs-plugin
- ];
- };
- services = {
- tumbler.enable = true;
- gnome.gnome-keyring.enable = true;
- };
- environment.systemPackages = with pkgs; [ file-roller ];
- })
-
- (lib.mkIf cfg.utils.enable {
- services.gvfs.enable = true;
-
- environment.systemPackages = with pkgs; [
- trashy
- gdu
-
- unzip
- p7zip
- unrar
- pxz
- pigz
- ];
- })
- ];
-}
diff --git a/sys/srv/gaming.nix b/sys/srv/gaming.nix
deleted file mode 100644
index ee7f608..0000000
--- a/sys/srv/gaming.nix
+++ /dev/null
@@ -1,50 +0,0 @@
-{ config, lib, pkgs, username, ... }:
-let
- cfg = config.sys.srv.gaming;
-in
-{
- options.sys.srv.gaming = {
- enable = lib.mkEnableOption "enables gaming utilities";
- steam.enable = lib.mkEnableOption "enables steam utilities";
- vr.enable = lib.mkEnableOption "enables vr support";
- };
- config = lib.mkMerge [
- (lib.mkIf cfg.enable {
- programs.gamescope.enable = true;
-
- programs.gamemode = {
- enable = true;
- enableRenice = true;
- };
-
- environment.systemPackages = with pkgs; [
- heroic
- prismlauncher
- ];
-
- home-manager.users.${username}.hm.soft.mangohud.enable = true;
- })
-
- (lib.mkIf cfg.steam.enable {
- programs.steam = {
- enable = true;
- localNetworkGameTransfers.openFirewall = true;
- dedicatedServer.openFirewall = true;
- remotePlay.openFirewall = false;
- extest.enable = true;
- protontricks.enable = true;
-
- extraCompatPackages = with pkgs; [
- proton-ge-custom
- ];
- };
- })
-
- (lib.mkIf cfg.vr.enable {
- programs.alvr = {
- enable = true;
- openFirewall = true;
- };
- })
- ];
-}
diff --git a/sys/srv/kvm.nix b/sys/srv/kvm.nix
deleted file mode 100644
index 2cf8c26..0000000
--- a/sys/srv/kvm.nix
+++ /dev/null
@@ -1,18 +0,0 @@
-{ config, lib, pkgs, ... }:
-let
- cfg = config.sys.srv.kvm;
-in
-{
- options.sys.srv.kvm.enable = lib.mkEnableOption "KVM/QEMU virtualization with Virt-Manager";
- config = lib.mkIf cfg.enable {
- virtualisation.libvirtd = {
- enable = true;
- qemu.package = pkgs.qemu_kvm;
- qemu.swtpm.enable = true;
- };
-
- programs.virt-manager.enable = true;
-
- boot.initrd.kernelModules = lib.optional (config.sys.core.drivers.amd.enable or false) "kvm-amd";
- };
-}
diff --git a/sys/srv/nix-helper.nix b/sys/srv/nix-helper.nix
deleted file mode 100644
index 5eb3353..0000000
--- a/sys/srv/nix-helper.nix
+++ /dev/null
@@ -1,23 +0,0 @@
-{ config, lib, pkgs, ... }:
-let
- cfg = config.sys.srv.nix-helper;
-in
-{
- options.sys.srv.nix-helper.enable = lib.mkEnableOption "enables nix-helper";
- config = lib.mkIf cfg.enable {
- nix.settings = {
- trusted-users = [ "root" "adam" ];
- experimental-features = [ "nix-command" "flakes" ];
- };
-
- programs.nh = {
- enable = true;
- flake = "/etc/nixos";
- };
-
- environment.systemPackages = with pkgs; [
- nix-output-monitor
- nvd
- ];
- };
-}
diff --git a/sys/srv/ollama.nix b/sys/srv/ollama.nix
deleted file mode 100644
index 11babd6..0000000
--- a/sys/srv/ollama.nix
+++ /dev/null
@@ -1,28 +0,0 @@
-{ config, lib, pkgs, ... }:
-let
- cfg = config.sys.srv.ollama;
-in
-{
- options.sys.srv.ollama.enable = lib.mkEnableOption "Ollama AI service";
- config = lib.mkIf cfg.enable {
- fileSystems."/models" = {
- device = "/home/ollama";
- fsType = "none";
- options = [ "bind" ];
- };
-
- services.ollama = {
- enable = true;
- package = pkgs.ollama-rocm;
-
- user = "ollama";
- models = "/models";
-
- syncModels = true;
- loadModels = [
- "deepseek-r1:14b"
- "qwen3:14b"
- ];
- };
- };
-}
diff --git a/sys/srv/srv.nix b/sys/srv/srv.nix
deleted file mode 100644
index 19e959e..0000000
--- a/sys/srv/srv.nix
+++ /dev/null
@@ -1,12 +0,0 @@
-{ ... }:
-{
- imports = [
- ./compat.nix
- ./docker.nix
- ./files.nix
- ./gaming.nix
- ./kvm.nix
- ./nix-helper.nix
- ./ollama.nix
- ];
-}
diff --git a/sys/wm/niri.nix b/sys/wm/niri.nix
deleted file mode 100644
index c92b068..0000000
--- a/sys/wm/niri.nix
+++ /dev/null
@@ -1,21 +0,0 @@
-{ inputs, config, lib, pkgs, username, ... }:
-let
- cfg = config.sys.wm.niri;
-in
-{
- imports = [ inputs.niri.nixosModules.niri ];
-
- options.sys.wm.niri.enable = lib.mkEnableOption "Niri";
-
- config = lib.mkIf cfg.enable {
- nixpkgs.overlays = [ inputs.niri.overlays.niri ];
-
- programs.niri = {
- enable = true;
- package = pkgs.niri-unstable;
- };
-
- sys.srv.compat.enable = true;
- home-manager.users.${username}.hm.env.niri.enable = true;
- };
-}
diff --git a/sys/wm/wm.nix b/sys/wm/wm.nix
deleted file mode 100644
index 5374264..0000000
--- a/sys/wm/wm.nix
+++ /dev/null
@@ -1,20 +0,0 @@
-{ config, lib, pkgs, ... }:
-let
- cfg = config.sys.wm;
-in
-{
- imports = [
- ./niri.nix
- ];
-
- options.sys.wm.enable = lib.mkEnableOption "enables shared wm features";
- config = lib.mkIf cfg.enable {
- services.dbus.enable = true;
-
- xdg.portal = {
- enable = true;
- xdgOpenUsePortal = true;
- extraPortals = [ pkgs.xdg-desktop-portal-gtk ];
- };
- };
-}
generated by cgit v1.3 (git 2.53.0) at 2026-08-17 07:39:26 +0000