modules/virtualization.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

{
  config,
  lib,
  pkgs,
  ...
}:
let
  cfg = config.os.srv.virtualization;
in
{
  options.os.srv.virtualization = {
    kvm.enable = lib.mkEnableOption "KVM/QEMU virtualization with Virt-Manager";
    waydroid.enable = lib.mkEnableOption "Waydroid Container Virtualization";
  };
  config = lib.mkMerge [
    (lib.mkIf cfg.kvm.enable {
      virtualisation.libvirtd = {
        enable = true;
        qemu.package = pkgs.qemu_kvm;
        qemu.swtpm.enable = true;
      };
      systemd.services.libvirt-guests.enable = false;
      programs.virt-manager.enable = true;

      boot.initrd.kernelModules =
        (lib.optional (config.os.core.drivers.cpu == "amd") "kvm-amd")
        ++ (lib.optional (config.os.core.drivers.cpu == "intel") "kvm-intel");
    })
    (lib.mkIf cfg.waydroid.enable {
      virtualisation.waydroid = {
        enable = true;
        package = pkgs.waydroid-nftables;
      };

      environment.systemPackages = with pkgs; [
        waydroid-helper
      ];
    })
  ];
}