os/core/drivers.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

{ config, lib, pkgs, ... }:
let
  cfg = config.os.core.drivers;
in
{
  options.os.core.drivers = {
    enable = lib.mkEnableOption "enables hardware drivers";
    amdgpu.enable = lib.mkEnableOption "AMD specific drivers and microcode";
    stability = lib.mkOption {
      type = lib.types.enum [ "stable" "unstable" ];
      default = "stable";
    };
  };
  config = lib.mkIf cfg.enable (lib.mkMerge [
    {
      programs.coolercontrol.enable = true;
      services.lact.enable = true;
      services.smartd.enable = true;
      hardware.sensor.iio.enable = true;
      hardware.enableAllFirmware = true;
      hardware.cpu.amd.updateMicrocode = true;
      hardware.graphics = {
        enable = true;
        enable32Bit = true;
        extraPackages = with pkgs; [
          rocmPackages.clr.icd
        ];
      };
      environment.systemPackages = [ pkgs.rivalcfg ];
    }

    (lib.mkIf cfg.amdgpu.enable {
      hardware.amdgpu = {
        initrd.enable = true;
        overdrive.enable = true;
      };
      boot.kernelParams = [ "amdgpu.gpu_recovery=1" ];
    })

    (lib.mkIf (cfg.amdgpu.enable && cfg.stability == "unstable") {
      boot.kernelPackages = pkgs.linuxPackages_latest;
      chaotic.mesa-git = {
        enable = true;
        fallbackSpecialisation = false;
        extraPackages = with pkgs; [
          rocmPackages.clr.icd
        ];
      };
    })

    (lib.mkIf (cfg.amdgpu.enable && cfg.stability == "stable") {
      boot.kernelPackages = pkgs.linuxPackages_6_12;
    })
  ]);
}