os/core/drivers.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99

{
  config,
  lib,
  pkgs,
  ...
}:
let
  cfg = config.os.core.drivers;
in
{
  options.os.core.drivers = {
    enable = lib.mkEnableOption "enables hardware drivers";

    cpu = lib.mkOption {
      type = lib.types.enum [
        "intel"
        "amd"
        "none"
      ];
      default = "none";
      description = "cpu manufacturer for microcode and platform-specific drivers";
    };

    graphics = {
      enable = lib.mkEnableOption "graphics support";
      amdgpu.enable = lib.mkEnableOption "amd specific gpu features";
    };

    kernel = lib.mkOption {
      type = lib.types.enum [
        "stable"
        "zen"
        "zfs"
        "hardened"
      ];
      default = "stable";
    };
  };

  config = lib.mkIf cfg.enable (
    lib.mkMerge [
      {
        hardware.enableAllFirmware = true;
        services = {
          smartd.enable = true;
          fwupd.enable = true;
        };
        environment.systemPackages = [ pkgs.rivalcfg ];
      }

      (lib.mkIf (cfg.cpu == "amd") {
        hardware.cpu.amd.updateMicrocode = true;
        programs.coolercontrol.enable = true;
      })

      (lib.mkIf (cfg.cpu == "intel") {
        hardware.cpu.intel.updateMicrocode = true;
        services.thermald.enable = true;
      })

      (lib.mkIf cfg.graphics.enable {
        hardware.graphics = {
          enable = true;
          enable32Bit = true;
        };
        hardware.sensor.iio.enable = true;
      })

      (lib.mkIf (cfg.graphics.enable && cfg.graphics.amdgpu.enable) {
        services = {
          lact.enable = true;
          hardware.openrgb.enable = true;
        };
        hardware = {
          amdgpu = {
            initrd.enable = true;
            overdrive.enable = true;
          };
          graphics.extraPackages = with pkgs; [
            rocmPackages.clr.icd
            libva-utils
          ];
        };
      })
      {
        boot.kernelPackages =
          let
            kernels = {
              "stable" = pkgs.linuxPackages_latest;
              "zen" = pkgs.linuxPackages_zen;
              "hardened" = pkgs.linuxPackages_hardened;
              "zfs" = config.boot.zfs.package.latestCompatibleLinuxPackages;
            };
          in
          kernels.${cfg.kernel} or kernels."stable";
      }
    ]
  );
}