os/core/users.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

{
  config,
  lib,
  pkgs,
  username,
  ...
}:
let
  cfg = config.os.core.users;
in
{
  options.os.core.users.enable = lib.mkEnableOption "enables user accounts";
  config = lib.mkIf cfg.enable {
    programs.fish.enable = true;
    assertions = [
      {
        assertion = config.os.srv.sops.enable;
        message = "required for storing the ssh key";
      }
    ];
    sops.secrets = {
      "users/root_password".neededForUsers = true;
      "users/main_password".neededForUsers = true;
      # "users/opc_password".neededForUsers = true;
    };
    users = {
      mutableUsers = false;

      users = {
        "${username}" = {
          isNormalUser = true;
          hashedPasswordFile = config.sops.secrets."users/main_password".path;
          shell = pkgs.fish;
          extraGroups = lib.mkMerge [
            [
              "wheel"
              "input"
              "uinput"
            ]

            (lib.mkIf (config.os.core.drivers.graphics.enable or false) [
              "video"
              "render"
            ])
            (lib.mkIf (config.os.core.network.enable or false) [ "networkmanager" ])
            (lib.mkIf (config.os.srv.virtualization.kvm.enable or false) [ "libvirtd" ])
            (lib.mkIf (config.os.srv.docker.enable or false) [ "docker" ])
          ];
        };
        root.hashedPasswordFile = config.sops.secrets."users/root_password".path;
      };
    };
  };
}