os/srv/gaming.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116

{
  config,
  lib,
  pkgs,
  username,
  ...
}:
let
  cfg = config.os.srv.gaming;
in
{
  options.os.srv.gaming = {
    enable = lib.mkEnableOption "enables general gaming support";

    tools.enable = lib.mkEnableOption "enables performance tools" // {
      default = cfg.enable;
    };
    launchers.enable = lib.mkEnableOption "enables 3rd party launchers" // {
      default = cfg.enable;
    };
    games.enable = lib.mkEnableOption "enables specific native games";
    steam.enable = lib.mkEnableOption "enables steam utilities";
    vr.enable = lib.mkEnableOption "enables vr support";
  };

  config = lib.mkMerge [
    # --- PERFORMANCE & TOOLING ---
    (lib.mkIf cfg.tools.enable {
      programs.gamescope = {
        enable = true;
        capSysNice = true;
      };

      programs.gamemode = {
        enable = true;
        enableRenice = true;
      };

      home-manager.users.${username}.hm.soft.mangohud.enable = true;

      environment.systemPackages = with pkgs; [
        ludusavi
        protonplus
      ];
    })

    # --- EXTERNAL LAUNCHERS ---
    (lib.mkIf cfg.launchers.enable {
      environment.systemPackages = with pkgs; [
        heroic
        (pkgs.bottles.override { removeWarningPopup = true; })
        (prismlauncher.override {
          additionalLibs = with pkgs; [ ocl-icd ];
          jdks = with pkgs; [ javaPackages.compiler.temurin-bin.jdk-25 ];
        })
      ];
    })

    # --- SPECIFIC GAMES ---
    (lib.mkIf cfg.games.enable {
      environment.systemPackages = with pkgs; [
        openttd-jgrpp
        openmw
        portmod
      ];
    })

    # --- STEAM ---
    (lib.mkIf cfg.steam.enable {
      programs.steam = {
        enable = true;
        localNetworkGameTransfers.openFirewall = true;
        dedicatedServer.openFirewall = true;
        remotePlay.openFirewall = false;
        extest.enable = true;
        protontricks.enable = true;
      };
      environment.systemPackages = with pkgs; [ steamtinkerlaunch ];
    })

    # --- VR SUPPORT ---
    (lib.mkIf cfg.vr.enable {
      programs.alvr = {
        enable = true;
        openFirewall = true;
        package = pkgs.alvr.overrideAttrs (
          finalAttrs: prevAttrs: {
            version = "20.13.0";

            src = pkgs.fetchFromGitHub {
              owner = "alvr-org";
              repo = "ALVR";
              tag = "v${finalAttrs.version}";
              fetchSubmodules = true;
              hash = "sha256-h7/fuuolxbNkjUbqXZ7NTb1AEaDMFaGv/S05faO2HIc=";
            };

            cargoDeps = pkgs.rustPlatform.fetchCargoVendor {
              inherit (finalAttrs) src;
              hash = "sha256-A0ADPMhsREH1C/xpSxW4W2u4ziDrKRrQyY5kBDn//gQ=";
            };
          }
        );
      };
      services.wivrn = {
        enable = true;
        openFirewall = true;
        highPriority = true;
        steam.importOXRRuntimes = true;
        defaultRuntime = true;
      };
      environment.systemPackages = [ pkgs.android-tools ];
      users.users.${username}.extraGroups = [ "adbusers" ];
    })
  ];
}