os/srv/headscale.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76

{
  config,
  lib,
  pkgs,
  masterDomain,
  ...
}:
let
  cfg = config.os.srv.headscale;
  aclPolicy = pkgs.writeText "headscale-policy.json" (
    builtins.toJSON {
      groups = {
        "group:admin" = [ "your-device-name" ];
        "group:friends" = [ "friend-device-name" ];
      };

      hosts = {
        "server" = "10.4.0.1";
      };

      acls = [
        {
          action = "accept";
          src = [ "group:admin" ];
          dst = [ "*:*" ];
        }

        {
          action = "accept";
          src = [ "group:friends" ];
          dst = [
            "server:18080"
            "server:18081"
            "server:25565"
          ];
        }
      ];
    }
  );
in
{
  options.os.srv.headscale.enable = lib.mkEnableOption "enables headscales";

  config = lib.mkIf cfg.enable {
    services.headscale = {
      enable = true;
      address = "127.0.0.1";
      port = 8080;

      settings = {
        server_url = "https://vpn.${masterDomain}";

        policy.path = "${aclPolicy}";

        dns = {
          magic_dns = true;
          base_domain = "vpn";
          nameservers = [ config.os.core.network.ips.vm2-gateway ];
        };

        ip_prefixes = [
          "10.4.0.0/16"
        ];
      };
    };

    services.nginx.virtualHosts."vpn.${masterDomain}" = {
      enableACME = true;
      forceSSL = true;
      locations."/" = {
        proxyPass = "http://127.0.0.1:8080";
        proxyWebsockets = true;
      };
    };
  };
}